SVN自动全备份及增量备份脚本，包含文件压缩，可加入window 任务

千寻 · 发表于 2008-12-23 14:21:38

一直用这套脚本备份，脚本主体虽不是原创，但是从网上得到后因为不能运行也进行了些修改，前两天看到有人问关于SVN备份的问题，今天又把脚本整理了一下，解决了不能循环备份多个配置库的问题。希望对大家有所帮助。在此也谢谢提供脚本主体的高人。
我的备份策略是一个月一次全备份，一周一次增量备份，并且每天也进行增量备份，在Window任务里设置定时进行，设置好后就不用管了，再加一层保险就是定期把备份文件移到另外一台机器存储。
（一）全备份,包含两个文件hotcopy.bat和最终执行文件fullbackup.bat
1) hotcopy.bat
@echo 正在备份版本库%1……
rem @%SVN_HOME%\bin\svnadmin hotcopy %1 %BACKUP_DIRECTORY%\%2
@%SVN_HOME%\svnadmin hotcopy %1 %BACKUP_DIRECTORY%\%2
@echo 版本库%1成功备份到了%2！

2)fullbackup.bat
echo off
rem Subversion的安装目录
rem set SVN_HOME="F:\Program Files\Subversion"
set SVN_HOME="F:\Program Files\CollabNet Subversion Server"
rem 所有版本库的父目录
set SVN_ROOT=G:\SVN
rem 备份的目录
set BACKUP_SVN_ROOT=h:\svnrootbak
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,10%

if exist %BACKUP_DIRECTORY% goto checkBack
echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/fullbackup.log
mkdir %BACKUP_DIRECTORY%
rem 验证目录是否为版本库，如果是则取出名称备份
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I\conf\svnserve.conf" hotcopy.bat "%%~fI" %%~nI
goto end
:checkBack
echo 备份目录%BACKUP_DIRECTORY%已经存在，请清空。
goto end
:end

（二）增量备份，包含三个文件，dump.bat、最终执行文件svndump.bat和配置库名称配置projectlist.conf
1）dump.bat
@ECHO OFF
rem 调用格式：dump 项目库名
if "%1"=="" goto no_args
set PROJECT=%1
if not exist %RAR_STORE%\%PROJECT% mkdir %RAR_STORE%\%PROJECT%
cd %RAR_STORE%\%PROJECT%
SET LOWER=0
SET UPPER=0

@echo 项目库%PROJECT%2...>> %Log_PATH%\%PROJECT%_log.txt
%SVN_LOOK% youngest %SVN_REPOROOT%\%PROJECT%> %Log_PATH%\A.TMP
@echo 项目库%PROJECT%3...>> %Log_PATH%\%PROJECT%_log.txt
@FOR /f %%D IN (%Log_PATH%\A.TMP) DO set UPPER=%%D
if %UPPER%==0 GOTO :N_EXIT
if not exist %Log_PATH%\%PROJECT%_last_revision.txt GOTO :BAKUP
rem 取出上次备份后的版本号，并做＋1处理(注意此算法未在98系统验证)
@FOR /f %%C IN (%Log_PATH%\%PROJECT%_last_revision.txt) DO @set LOWER=%%C
@set /A LOWER=%LOWER%+1
rem 不需要备份，则跳转结束
IF %LOWER% gtr %UPPER% GOTO :N_EXIT

:BAKUP
SET FILENAME=%PROJECT%_%LOWER%_%UPPER%
@ECHO 开始备份项目库：%PROJECT%，生成文件=%FILENAME%
%SVN_ADMIN% dump %SVN_REPOROOT%\%PROJECT% -r %LOWER%:head --incremental >%FILENAME%.dmp
rem %RAR_CMD% a -df %PROJECT%_%UPPER%.rar %
rem 准备写备份日志信息
IF %LOWER% gtr 0 GOTO :WRITENOTE
@ECHO ------2-----%date% >> %Log_PATH%\%PROJECT%_log.txt
@echo  -- 3-------添加备份文件 %PROJECT%_%UPPER%.rar，从[%LOWER%]到[%UPPER%] >> %Log_PATH%\%PROJECT%_log.txt
GOTO :COMPLETE

:WRITENOTE
@ECHO %date% >> %Log_PATH%\%PROJECT%_log.txt
@echo  -- 4------添加增量备份文件 %PROJECT%_%UPPER%.rar，从[%LOWER%]到[%UPPER%] >> %Log_PATH%\%PROJECT%_log.txt

:COMPLETE
rem 下面一行用于拷贝备份文件到映射的驱动器上
rem copy %PROJECT%.rar %RAR_STORE%\%PROJECT%\
move %FILENAME%.dmp %RAR_STORE%\%PROJECT%\
del %Log_PATH%\A.TMP
@echo %UPPER% > %Log_PATH%\%PROJECT%_last_revision.txt

:N_EXIT
@echo 项目库%PROJECT%处理结束...>> %Log_PATH%\%PROJECT%_log.txt
@CD..
@exit /B
:no_args
@ECHO ON
@echo "正确调用方法： dump 项目库名"

2）svndump.bat
echo off
rem Subversion的安装目录及执行文件
set SVN_HOME="F:\Program Files\CollabNet Subversion Server"
set SVN_ADMIN=%SVN_HOME%\svnadmin.exe
set SVN_LOOK=%SVN_HOME%\svnlook.exe
rem 配置库仓库根目录
set SVN_REPOROOT=G:\SVN
rem 压缩命令
set RAR_CMD="E:\Progra~1\WinRAR\WinRAR"
rem 增量备份文件存放路径
set RAR_STORE="H:\svnincrementW"
rem 日志及最后一次备份修订号存放文件目录，以下是跟增量备份脚本目录同一目录
set Log_PATH=G:\backup\incrementW

@echo 项目库%PROJECT%处理1...>> %Log_PATH%\%PROJECT%_log.txt
rem 读取项目库列表文件，并忽略其中;开头的行
FOR /f "eol=;" %%C IN (projectlist.conf) DO  call G:\backup\incrementW\dump.bat %%C

3）projectlist.conf
;**************************************************
;01. project1开发库
; 更新频率: 高
;**************************************************
PROJECT1
;**************************************************
;02. 此处可写注释信息
;**************************************************
PROJECT2
PROJECT3
PROJECT4
PROJECT5

[ 本帖最后由千寻于 2008-12-23 14:26 编辑 ]

CMStruggling · 发表于 2008-12-23 15:48:51

感谢千寻千大人分享关于SVN自动备份的脚本；
大家的福音啊！！！

go2cxg · 发表于 2008-12-24 11:18:08

感谢版主分享~
呵呵
分享互助共进~

moke_lee · 发表于 2008-12-24 12:41:43

现在的数据库比较大，主要是项目有一些库文件有1G大小。整个项目大小在2.5G，所以在现在只有1000个版本是备份大小已经超过了5G，速度很慢。是否可以分段备份一些，这样以后只备份后续的部分即可？

go2cxg · 发表于 2008-12-24 13:09:51

可以选择备份一部分
部分版本即可

ancestor · 发表于 2008-12-25 14:20:02

谢谢分享，我习惯把备份写成windows服务，来代替计划任务

zllzh6402929 · 发表于 2009-2-19 17:13:28

全力支持！！！喜欢！

xiyufenfei · 发表于 2009-8-17 22:34:20

楼主厉害谢谢啊

howtoesc · 发表于 2009-8-18 11:00:49

看了你的脚本，才知道有磁带机和专门的备份工程师是多么幸福的一件事。

redling · 发表于 2010-2-23 16:40:23

LZ,你这个增量备份的脚本如何使用 ? 能给个说明吗?
还有完全备份的脚本,我用了,目标备份目录如果不是空的话,执行脚本会报错,并不会去删除....

帐号		自动登录	找回密码
密码			立即注册

[推荐] SVN自动全备份及增量备份脚本，包含文件压缩，可加入window 任务

本帖子中包含更多资源

评分

本帖被以下淘专辑推荐:

回复楼主的帖子

有没有分段备份的！

回复楼主的帖子

SCMLife推荐 /4

[推荐] SVN自动全备份及增量备份脚本，包含文件压缩，可加入window 任务

本帖子中包含更多资源

评分

本帖被以下淘专辑推荐:

回复 楼主 的帖子

有没有分段备份的！

回复 楼主 的帖子

SCMLife推荐 /4

回复楼主的帖子

回复楼主的帖子